home *** CD-ROM | disk | FTP | other *** search
/ C/C++ Users Group Library 1996 July / C-C++ Users Group Library July 1996.iso / vol_100 / 137_01 / llsup.asm < prev    next >
Assembly Source File  |  1985-03-09  |  5KB  |  209 lines
  1. ;
  2. ; llsup.asm
  3. ;
  4. ; a component of lsup.c
  5. ;
  6. ; Copyright 1984 (c) A. Skjellum. All rights reserved.
  7. ; 
  8. ; version of 25-Mar-84
  9. ;
  10. ; This routine makes no assumptions about the behavior of the
  11. ; C compiler in use.
  12. ;
  13. ; all procedures are "near"
  14. ;
  15.  
  16. dseg    segment para public 'data'
  17. dseg    ends
  18.  
  19. cseg    segment para public 'code'
  20.     assume    cs:cseg,ds:dseg
  21.  
  22. ;
  23. ; linc:        increment a long pointer by 1 byte
  24. ;
  25. ; expects:    es:bx with long pointer to increment
  26. ; returns:    pointer incremented.
  27. ; consumes:    es, bx, f, ax
  28. ;
  29.     public    linc
  30. linc    proc    near
  31.     inc    bx        ; increment low part of word
  32.     or    bx,bx        ; is it zero now?
  33.     jnz    linc_exit    ; no, we are done
  34.     mov    ax,es
  35.     add    ax,1000h    ; another 64k of paragraphs
  36.     mov    es,ax        ; store back to es
  37. linc_exit:
  38.     ret            ; return
  39. linc    endp
  40.  
  41. ;
  42. ; ldec:        decrement a long pointer by 1 byte
  43. ;
  44. ; expects:    es:bx with long pointer to decrement
  45. ; returns:    pointer decremented.
  46. ; consumes:    es, bx, f, ax
  47. ;
  48.     public    ldec
  49. ldec    proc    near
  50.     or    bx,bx        ; zero currently ?
  51.     dec    bx        ; decrement it
  52.     jnz    ldec_exit    ; just decrement low end and exit...
  53.     mov    ax,es        ; get segment register
  54.     sub    ax,1000h    ; remove 64k of paragraphs
  55.     mov    es,ax        ; store back to es
  56. ldec_exit:
  57.     ret            ; return
  58. ldec    endp
  59.  
  60. ;
  61. ; ladd:        add a constant to a long pointer
  62. ;
  63. ; expects:    es:bx with long pointer's original value
  64. ;        ax with unsigned constant to be added
  65. ; returns:    pointer with constant added
  66. ; consumes:    es, bx, f, ax
  67. ;
  68.     public    ladd
  69. ladd    proc    near
  70.     add    bx,ax        ; add in offset
  71.     jnc    ladd_exit    ; no carry, so we are done.
  72.     mov    ax,es
  73.     add    ax,1000h    ; add 64k of paragraphs
  74.     mov    es,ax        ; and store back to es
  75. ladd_exit:
  76.     ret
  77. ladd    endp
  78.  
  79. ;
  80. ; lsub:        subtract a constant from a long pointer
  81. ;
  82. ; expects:    es:bx with long pointer's original value
  83. ;        ax with unsigned constant to be subtracted
  84. ; returns:    pointer with constant subtracted
  85. ; consumes:    es, bx, f, ax
  86. ;
  87.     public    lsub
  88. lsub    proc    near
  89.     sub    bx,ax        ; subtract offset
  90.     jnb    lsub_exit    ; no borrow, so we are done.
  91.     mov    ax,es
  92.     sub    ax,1000h    ; subtract 64k of paragraphs
  93.     mov    es,ax        ; and store back to es
  94. lsub_exit:
  95.     ret
  96. lsub    endp
  97.  
  98. ;
  99. ; lsum:        add a signed offset to a long pointer
  100. ;
  101. ; expects:    es:bx with long pointer
  102. ;        ax with signed offset
  103. ; returns:    pointer with constant added (signed)
  104. ; consumes:    es, bx, f, ax
  105. ;
  106.     public    lsum
  107. lsum    proc    near
  108.     or    ax,ax        ; negative?
  109.     jm    lsum_neg
  110.     call    ladd        ; do addition
  111.     ret            ; and exit
  112. lsum_neg:
  113.     and    ax,07fffh    ; and out sign flag
  114.     jnz    lsum_neg_ok
  115.     mov    ax,8000h    ; -32768 value (don't treat as 0)
  116. lsum_neg_ok:
  117.     call    lsub
  118.     ret
  119. lsum    endp
  120.  
  121. ;
  122. ; lcopy:    copy from one long pointer to another,
  123. ;        up to 1024k bytes of data
  124. ;
  125. ; expects:    ds:si with src  address
  126. ;        es:di with dest address
  127. ;        ds|cx with length (dx is high order, cx is low order)
  128. ;        
  129. ; returns:    block copied
  130. ;        ds, es intact
  131. ; consumes:    ax, cx, f
  132. ;
  133. ;
  134. ;     this routine uses a copy downward method, to produce
  135. ;    correct copying for overlapping regions
  136. ;
  137.     public    lcopy
  138. lcopy    proc    near
  139.     ;
  140.     ; convert dx into segment form:
  141.     ;
  142.     push    dx        ; save original form of dx
  143.     push    cx        ; save low order of long count
  144.     and    dx,15        ; smallest meaningful value
  145.     xchg    dh,dl        ; switch upper and lower parts
  146.     mov    cl,4
  147.     shl    dh,cl        ; effect is shift left by 12 bits
  148.     pop    cx        ; and recover low order of long count
  149.     ;
  150.     mov    ax,es
  151.     add    ax,dx
  152.     mov    es,ax
  153.     mov    ax,ds
  154.     add    ax,dx
  155.     mov    ds,ax        ; gross adjustment of segments
  156.     pop    dx        ; recover original form of dx
  157.     ;    
  158.     add    di,cx        ; adjust dest. ptr to end of area
  159.     jnc    no_dest_adj    
  160.     mov    ax,es
  161.     add    ax,1000h    ; add offset
  162.     mov    es,ax        ; and store back to segment register
  163. no_dest_adj:
  164.     ;
  165.     ; do same work for source pointer:
  166.     ;
  167.     add    si,cx        ; do the addition
  168.     jnc    no_mor_adj    ; no more adjustment needed if no carry
  169.     mov    ax,ds
  170.     add    ax,1000h    ; do the adjustment
  171.     mov    ds,ax        ; and store back to ds
  172.     ;
  173.     ; at this stage: 
  174.     ;
  175.     ;    es:di is at the last byte of the dest. area
  176.     ;    ds:si is at the last byte of the src.  area
  177.     ;
  178. no_mor_adj:
  179.     std            ; set direction flag for moves
  180. lc_loop:
  181.     or    si,si        ; is si zero ?
  182.     lodsb             ; get byte ds:[si], decrement si
  183.     jnz    no_ds_adj    ; no need to adjust if non-zero at start
  184.     mov    ax,ds
  185.     sub    ax,1000h
  186.     mov    ds,ax        ; adjust pointer for next load
  187. no_ds_adj:
  188.     or    di,di        ; is di zero ?
  189.     stosb            ; set byte es:[di] = al, decrement di
  190.     jnz    no_es_adj    ; no need to adjust if non-zero at start
  191.     mov    ax,es
  192.     sub    ax,1000h    
  193.     mov    es,ax        ; adjust pointer for next store
  194. no_es_adj:
  195.     loop    lc_loop        ; copy whole block (--cx, jnz lc_loop)
  196.     dec    dx        ; work on outer loop
  197.     or    dx,dx
  198.     jnz    lc_loop        ; loop over dx counts too
  199.     ;
  200.     ; we are done
  201.     ;
  202.     inc    si
  203.     inc    di        ; restore to original calling values
  204.     ret            ; exit
  205. lcopy    endp
  206.  
  207. cseg    ends
  208.     end
  209.